User Tools

Site Tools


ad_ul_data_logger

Documentation Home

BASIC INFORMATION

Name: Uno-Leonardo Data Logger
Type: Arduino Shield
Version: 1.0.0
Author: Dubravko Penezic
Copyright: Creative Commons BY-NC-SA v 3.0
Implemented function:

PCB Top & Bottom image


Used Pins

Arduino Leonardo Compatibility

Digital Pin: 0, 1, 2, 3, 4, 6, 7, 8, 9
Analogue Pin: 3, special (6, 7)
Bus: ICSP, TWI
Power Pin: GND, +5V, +3.3V
Other Pin: RESET

Arduino Uno Compatibility

Digital Pin: 0, 1, 4, 6, 7, 8, 9, 11, 12, 13
Analogue Pin: 3, 4, 5, special (6, 7)
Bus: ICSP, TWI
Power Pin: GND, +5V, +3.3V
Other Pin: RESET

Schematic

Schematic are available in follow file : dl_v_1_0_0.pdf

Functional example

Code example

To compile follow code you will also need libraries DpFormatNumber and DpDS1307 available in libraries.zip file.

// Author: Dubravko Penezic

// Version: 1.0, 2012

// Read data from barometic sensor, and two LM35 sensors, gether date and time from RTC, and save data to text file on SD card

// Source code is provided as is, without any warranty.

// Distributetd under CC BY v 3.0

// Barometric sensor variable

#include <Wire.h>

#define BMP085_ADDRESS 0x77  // I2C address of BMP085

const unsigned char OSS = 0;  // Oversampling Setting

// Calibration values
int ac1;
int ac2; 
int ac3; 
unsigned int ac4;
unsigned int ac5;
unsigned int ac6;
int b1; 
int b2;
int mb;
int mc;
int md;

// b5 is calculated in bmp085GetTemperature(...), this variable is also used in bmp085GetPressure(...)
// so ...Temperature(...) must be called before ...Pressure(...).
long b5; 

short b_temperature;
long b_pressure;

// Use these for altitude conversions
const float p0 = 101325;     // Pressure at sea level (Pa)
float b_altitude;


// temperature LM35 sensor variable

float lm1_temperature;
int lm1_tempPin = 0;
float lm2_temperature;
int lm2_tempPin = 1;

// format numbers
#include <DpFormatNumber.h>

DpFormatNumber fN;
char pn[9];

// RTC lib
#include <DpDS1307.h>

DpDS1307 RTC=DpDS1307();

// include the SD library:
#include <SD.h>
File myFile;

String file_name = "";

void setup()
{
  Serial.begin(9600);
  pinMode(10, OUTPUT);
  Wire.begin();
  bmp085Calibration();
  // make sure that the default chip select pin is set to
  // output, even if you don't use it:
  pinMode(7, OUTPUT);
  digitalWrite(7, HIGH);

 // see if the card is present and can be initialized:
 if (!SD.begin(7)) {
  Serial.println("Card failed, or not present");
  // don't do anything more:
  return;
 }
 RTC.startClock(); 
}

void loop()
{
  String raw = "";
//  Serial.println(freeRam());
  RTC.getTime();
  fN.UnsInt2ForStr(RTC.year,5,true,pn);
  raw = raw + pn +"-";
  fN.UnsInt2ForStr(RTC.month,3,true,pn);
  raw = raw + pn +"-";
  fN.UnsInt2ForStr(RTC.day,3,true,pn);
  raw = raw + pn +" ";
  fN.UnsInt2ForStr(RTC.hour,3,true,pn);
  raw = raw + pn +":";
  fN.UnsInt2ForStr(RTC.minute,3,true,pn);
  raw = raw + pn +":";
  fN.UnsInt2ForStr(RTC.second,3,true,pn);
  raw = raw + pn;
  raw.replace("- ","-0");
  raw.replace("  "," 0");
  raw.replace(": ",":0");
  
  file_name = raw;
  file_name.replace("-","");
  file_name.replace(" ","");
  file_name.replace(":","");
  file_name = file_name + ".txt";
  file_name_not_exist = false;

  raw = raw +";";
  
  b_pressure = bmp085GetPressure(bmp085ReadUP());
  fN.SigLon2ForStr(b_pressure, 8, false, pn);
  raw = raw + pn +";";
  
  b_altitude = (float)44330 * (1 - pow(((float) b_pressure/p0), 0.190295));
  fN.Float2ForStr(b_altitude,9, 2, false, pn);
  raw = raw + pn +";";
  
  b_temperature = bmp085GetTemperature(bmp085ReadUT());
  fN.Float2ForStr((float)b_temperature/10,7,1,false, pn);
  raw = raw + pn +";";
  
  lm1_temperature = analogRead(lm1_tempPin); //read the value from the sensor
  lm1_temperature = (5.0 * lm1_temperature * 100.0)/1024.0; //convert the analog data to temperature
  fN.Float2ForStr(lm1_temperature,8, 2, false, pn);
  raw = raw + pn +";";

  lm2_temperature = analogRead(lm2_tempPin); //read the value from the sensor
  lm2_temperature = (5.0 * lm2_temperature * 100.0)/1024.0; //convert the analog data to temperature
  fN.Float2ForStr(b_altitude,8, 2, false, pn);
  raw = raw + pn +";";
  
  Serial.println(raw);
  
  char fn[24];
  file_name.substring(3,11).toCharArray(fn,9);
  Serial.println(fn);
  myFile = SD.open(fn, FILE_WRITE);
 
  // if the file opened okay, write to it:
  if (myFile) {
    myFile.println(raw);
    // close the file:
    myFile.close();
  } else {
    // if the file didn't open, print an error:
    Serial.println("error opening "+file_name);
  }
  
  delay(5000);
}

// Stores all of the bmp085's calibration values into global variables
// Calibration values are required to calculate temp and pressure
// This function should be called at the beginning of the program
void bmp085Calibration()
{
  ac1 = bmp085ReadInt(0xAA);
  ac2 = bmp085ReadInt(0xAC);
  ac3 = bmp085ReadInt(0xAE);
  ac4 = bmp085ReadInt(0xB0);
  ac5 = bmp085ReadInt(0xB2);
  ac6 = bmp085ReadInt(0xB4);
  b1 = bmp085ReadInt(0xB6);
  b2 = bmp085ReadInt(0xB8);
  mb = bmp085ReadInt(0xBA);
  mc = bmp085ReadInt(0xBC);
  md = bmp085ReadInt(0xBE);
}

// Calculate temperature given ut.
// Value returned will be in units of 0.1 deg C
short bmp085GetTemperature(unsigned int ut)
{
  long x1, x2;
  
  x1 = (((long)ut - (long)ac6)*(long)ac5) >> 15;
  x2 = ((long)mc << 11)/(x1 + md);
  b5 = x1 + x2;

  return ((b5 + 8)>>4);  
}

// Calculate pressure given up
// calibration values must be known
// b5 is also required so bmp085GetTemperature(...) must be called first.
// Value returned will be pressure in units of Pa.
long bmp085GetPressure(unsigned long up)
{
  long x1, x2, x3, b3, b6, p;
  unsigned long b4, b7;
  
  b6 = b5 - 4000;
  // Calculate B3
  x1 = (b2 * (b6 * b6)>>12)>>11;
  x2 = (ac2 * b6)>>11;
  x3 = x1 + x2;
  b3 = (((((long)ac1)*4 + x3)<<OSS) + 2)>>2;
  
  // Calculate B4
  x1 = (ac3 * b6)>>13;
  x2 = (b1 * ((b6 * b6)>>12))>>16;
  x3 = ((x1 + x2) + 2)>>2;
  b4 = (ac4 * (unsigned long)(x3 + 32768))>>15;
  
  b7 = ((unsigned long)(up - b3) * (50000>>OSS));
  if (b7 < 0x80000000)
    p = (b7<<1)/b4;
  else
    p = (b7/b4)<<1;
    
  x1 = (p>>8) * (p>>8);
  x1 = (x1 * 3038)>>16;
  x2 = (-7357 * p)>>16;
  p += (x1 + x2 + 3791)>>4;
  
  return p;
}

// Read 1 byte from the BMP085 at 'address'
char bmp085Read(unsigned char address)
{
  unsigned char data;
  
  Wire.beginTransmission(BMP085_ADDRESS);
  Wire.write(address);
  Wire.endTransmission();
  
  Wire.requestFrom(BMP085_ADDRESS, 1);
  while(!Wire.available())
    ;
    
  return Wire.read();
}

// Read 2 bytes from the BMP085
// First byte will be from 'address'
// Second byte will be from 'address'+1
int bmp085ReadInt(unsigned char address)
{
  unsigned char msb, lsb;
  
  Wire.beginTransmission(BMP085_ADDRESS);
  Wire.write(address);
  Wire.endTransmission();
  
  Wire.requestFrom(BMP085_ADDRESS, 2);
  while(Wire.available()<2)
    ;
  msb = Wire.read();
  lsb = Wire.read();
  
  return (int) msb<<8 | lsb;
}

// Read the uncompensated temperature value
unsigned int bmp085ReadUT()
{
  unsigned int ut;
  
  // Write 0x2E into Register 0xF4
  // This requests a temperature reading
  Wire.beginTransmission(BMP085_ADDRESS);
  Wire.write(0xF4);
  Wire.write(0x2E);
  Wire.endTransmission();
  
  // Wait at least 4.5ms
  delay(5);
  
  // Read two bytes from registers 0xF6 and 0xF7
  ut = bmp085ReadInt(0xF6);
  return ut;
}

// Read the uncompensated pressure value
unsigned long bmp085ReadUP()
{
  unsigned char msb, lsb, xlsb;
  unsigned long up = 0;
  
  // Write 0x34+(OSS<<6) into register 0xF4
  // Request a pressure reading w/ oversampling setting
  Wire.beginTransmission(BMP085_ADDRESS);
  Wire.write(0xF4);
  Wire.write(0x34 + (OSS<<6));
  Wire.endTransmission();
  
  // Wait for conversion, delay time dependent on OSS
  delay(2 + (3<<OSS));
  
  // Read register 0xF6 (MSB), 0xF7 (LSB), and 0xF8 (XLSB)
  Wire.beginTransmission(BMP085_ADDRESS);
  Wire.write(0xF6);
  Wire.endTransmission();
  Wire.requestFrom(BMP085_ADDRESS, 3);
  
  // Wait for data to become available
  while(Wire.available() < 3)
    ;
  msb = Wire.read();
  lsb = Wire.read();
  xlsb = Wire.read();
  
  up = (((unsigned long) msb << 16) | ((unsigned long) lsb << 8) | (unsigned long) xlsb) >> (8-OSS);
  
  return up;
}

// function for chacking mememory leek
// int freeRam () {
// extern int __heap_start, *__brkval;
// int v;
// return (int) &v - (__brkval == 0 ? (int) &__heap_start : (int) __brkval);
//}
ad_ul_data_logger.txt · Last modified: 2016/09/01 14:17 (external edit)